Browse our source — we have nothing to hide :)

<!--#include virtual="/page.asp"-->
<!--#include virtual="/ajaxed/class_dropdown/dropdown.asp"-->
<%
set sources = (new DataContainer)(array( _
    "/article.asp", _
    "/articles.asp", _
    "/page.asp", _
    "/default.asp", _
    "/about/default.asp", _
    "/api/default.asp", _
    "/app/article.asp", _
    "/app/sourceCode.asp", _
    "/feed/default.asp", _
    "/contact/default.asp", _
    "/discuss/default.asp", _
    "/source/default.asp", _
    "/ajaxedConfig/header.asp", _
    "/ajaxedConfig/footer.asp" _
))
page.title = "source code"
page.draw()

'******************************************************************************************
'* drawSourceDD 
'******************************************************************************************
sub drawSourceDD()
    with new Dropdown
        .datasource = sources.data
        .commonFieldText = "- source file -"
        .commonFieldValue = ""
        .name = "src"
        .attributes = "onchange=""$('frm').submit()"""
        .selectedValue = getSrc()
        .draw()
    end with
end sub

'******************************************************************************************
'* getSrc 
'******************************************************************************************
function getSrc()
    getSrc = lib.iif(page.isPostback(), page.RF("src"), "/source/default.asp")
end function

'******************************************************************************************
'* main 
'******************************************************************************************
sub main() %>
    
    <div class="contentAlt">
        <div class="content">
            <h1>Browse our source — we have nothing to hide :)</h1>
        </div>
    </div>
    
    <div class="content text">
        We believe that it is always best to learn from real world examples.
        For this reason you can browse all the source code (almost) of ajaxed.org here on this page.
        <br/>
        See ajaxed in action and learn... 
        
        <br/><br/>
        <form action="default.asp" method="post" id="frm">
            <label>Select source file:</label>
            <% drawSourceDD() %>
        </form>
    </div>
    
    <div class="text" style="padding:1em;">
        <% if sources.contains(getSrc()) then str.write((new Sourcecode)(getSrc())) %>
    </div>
    
    <div class="content text">    
        <blockquote>
            <strong>Note:</strong> As those sources come from a real
            production system they may lack a bit of documentation.
            It is a production system. We had to deliver quickly :)
        </blockquote>
    </div>
    
    <div class="contentAlt">
        <div class="content">
            <h2>
                Did you know that it took only 3 days to develop ajaxed.org?
            </h2>
        </div>
    </div>

<% end sub %>